Enable actualbudget on alto

hosts/alto/default.nix

@@ -17,9 +17,14 @@ in
         target = "localhost:${toString myConfig.hedgedoc.port}";
       };
 
-      caddyServe.nextcloud = {
+      caddyServe = {
+        nextcloud = {
           inherit (myConfig.nextcloud) subdomain port;
         };
+        actualbudget = {
+          inherit (myConfig.actualbudget) subdomain port;
+        };
+      };
     };
 
     nextcloud = {
@@ -27,6 +32,11 @@ in
       backups.enable = true;
       subdomain = "cloud";
     };
+    actualbudget = {
+      enable = true;
+      backups.enable = true;
+      subdomain = "budget";
+    };
     hedgedoc = {
       enable = true;
       backups.enable = true;

modules/system/actualbudget/backups.nix

@@ -0,0 +1,33 @@
+{
+  config,
+  pkgs,
+  lib,
+  ...
+}:
+{
+  options.myConfig.actualbudget.backups.enable = lib.mkEnableOption "";
+
+  config = lib.mkIf config.myConfig.actualbudget.backups.enable {
+    myConfig.resticBackup.actual = {
+      enable = true;
+      healthchecks.enable = true;
+
+      extraConfig = {
+        backupPrepareCommand = "${lib.getExe' pkgs.systemd "systemctl"} stop actual.service";
+        backupCleanupCommand = "${lib.getExe' pkgs.systemd "systemctl"} start actual.service";
+        paths = [ "/var/lib/actual" ];
+      };
+    };
+
+    environment.systemPackages = [
+      (pkgs.writeShellApplication {
+        name = "actual-restore";
+        text = ''
+          sudo systemctl stop actual.service
+          sudo restic-actual restore latest --target /
+          sudo systemctl start actual.service
+        '';
+      })
+    ];
+  };
+}

modules/system/actualbudget/default.nix

@@ -0,0 +1,44 @@
+{
+  config,
+  inputs,
+  pkgs-unstable,
+  lib,
+  ...
+}:
+let
+  cfg = config.myConfig.actualbudget;
+in
+{
+  disabledModules = [ "services/web-apps/actual.nix" ];
+  imports = [ "${inputs.nixpkgs-unstable}/nixos/modules/services/web-apps/actual.nix" ];
+
+  options.myConfig.actualbudget = {
+    enable = lib.mkEnableOption "";
+    subdomain = lib.mkOption {
+      type = lib.types.nonEmptyStr;
+      default = "";
+    };
+    port = lib.mkOption {
+      type = lib.types.port;
+      default = 8080;
+    };
+  };
+
+  config = lib.mkIf cfg.enable {
+    users.groups.actual = { };
+    users.users.actual = {
+      isSystemUser = true;
+      group = "actual";
+    };
+
+    services.actual = {
+      enable = true;
+      package = pkgs-unstable.actual-server;
+
+      settings = {
+        hostname = "localhost";
+        inherit (cfg) port;
+      };
+    };
+  };
+}