Complete overhaul

modules/home/default.nix

@@ -0,0 +1,10 @@
+{
+  imports = [
+    ./qtile
+    ./vscode.nix
+    ./shell.nix
+    ./theming.nix
+    ./ssh-client.nix
+    ./git.nix
+  ];
+}

modules/home/git.nix

@@ -0,0 +1,20 @@
+{
+  config,
+  lib,
+  ...
+}: {
+  options.myConfig.git.enable = lib.mkEnableOption "";
+
+  config = lib.mkIf config.myConfig.git.enable {
+    programs.git = {
+      enable = true;
+
+      userName = "SebastianStork";
+      userEmail = "sebastian.stork@pm.me";
+
+      extraConfig = {
+        init.defaultBranch = "main";
+      };
+    };
+  };
+}

modules/home/qtile/default.nix

@@ -0,0 +1,44 @@
+{
+  config,
+  pkgs,
+  lib,
+  osConfig,
+  ...
+}: {
+  options.myConfig.qtile.enable = lib.mkEnableOption "";
+
+  config = lib.mkIf config.myConfig.qtile.enable {
+    assertions = [
+      {
+        assertion = osConfig.services.xserver.windowManager.qtile.enable;
+        message = "Qtile has to be enabled on the system level";
+      }
+    ];
+
+    home.file.".config/qtile/config.py".source = ./files/qtile.py;
+    home.file.".background-image".source = ./files/background-image;
+
+    home.packages = [
+      # Widget dependencies
+      pkgs.python311Packages.iwlib
+      pkgs.python311Packages.psutil
+      pkgs.lm_sensors
+
+      # Hotkey dependencies
+      pkgs.playerctl
+      pkgs.brightnessctl
+    ];
+
+    programs.rofi = {
+      enable = true;
+      theme = ./files/rofi-theme.rasi;
+    };
+
+    services.picom = {
+      enable = true;
+      vSync = true;
+    };
+
+    services.dunst.enable = true;
+  };
+}

modules/home/qtile/files/qtile.py

@@ -0,0 +1,171 @@
+import os
+import subprocess
+
+from libqtile import bar, layout, widget
+from libqtile.config import Click, Drag, Group, Key, Match, Screen
+from libqtile.lazy import lazy
+from libqtile import hook
+
+# Constants
+mod = "mod4"
+terminal = "kitty"
+browser = "brave"
+editor = "notepadqq --new-window"
+fileManager = "nemo"
+
+lightBlue = "#739BD0"
+lightGrey = "#bcbcbc"
+
+left = "Left"
+right = "Right"
+down = "Down"
+up = "Up"
+
+
+### SHORTCUTS ###
+keys = [
+	# Essentials
+	Key([mod, "shift"], "c", lazy.window.kill(), desc="Kill focused window"),
+	Key([mod, "control"], "r", lazy.reload_config(), desc="Reload the config"),
+	Key([mod, "control"], "q", lazy.shutdown(), desc="Shutdown Qtile"),
+
+	# Launch programs
+	Key([mod], "Return", lazy.spawn(terminal), desc="Launch terminal"),
+	Key([mod], "r", lazy.spawn("rofi -show drun"), desc="Spawn a command using a prompt widget"),
+	Key([mod, "shift"], "r", lazy.spawn("rofi -show run"), desc="Spawn a command using a prompt widget"),
+	Key([mod], "b", lazy.spawn(browser), desc="launch browser"),
+	Key([mod], "n", lazy.spawn(editor), desc="launch notepadqq"),
+	Key([mod], "f", lazy.spawn(fileManager), desc="launch file manager"),
+	Key([mod], "c", lazy.spawn("codium"), desc="launch vscodium"),
+	Key([mod], "s", lazy.spawn("spotify"), desc="launch spotify"),
+	Key([mod], "v", lazy.spawn("clipmenu"), desc="launch clipmenu"),
+	
+	# Media controls
+	Key([], "XF86AudioPlay", lazy.spawn("playerctl --player=ncspot,spotify play-pause "), desc="Play and pause spotify"),
+	Key([], "XF86AudioMute", lazy.spawn("wpctl set-mute @DEFAULT_AUDIO_SINK@ toggle"), desc="Mute and unmute"),
+	Key([], "XF86AudioLowerVolume", lazy.spawn("wpctl set-volume @DEFAULT_AUDIO_SINK@ 5%-"), desc="Lower volume"),
+	Key([], "XF86AudioRaiseVolume", lazy.spawn("wpctl set-volume @DEFAULT_AUDIO_SINK@ 5%+"), desc="Raise volume"),
+
+	# Brightness controls
+	Key([], "XF86MonBrightnessUp", lazy.spawn("brightnessctl set +5%"), desc="Raise brightness"),
+	Key([], "XF86MonBrightnessDown", lazy.spawn("brightnessctl set 5%-"), desc="Lower brightness"),
+
+	# Move window focus
+	Key([mod], left, lazy.layout.left(), desc="Move focus to left"),
+	Key([mod], right, lazy.layout.right(), desc="Move focus to right"),
+	Key([mod], down, lazy.layout.down(), desc="Move focus down"),
+	Key([mod], up, lazy.layout.up(), desc="Move focus up"),
+	Key([mod], "space", lazy.layout.next(), desc="Move window focus to other window"),
+    
+	# Move windows
+	Key([mod, "shift"], left, lazy.layout.shuffle_left(), desc="Move window to the left"),
+	Key([mod, "shift"], right, lazy.layout.shuffle_right(), desc="Move window to the right"),
+	Key([mod, "shift"], down, lazy.layout.shuffle_down(), desc="Move window down"),
+	Key([mod, "shift"], up, lazy.layout.shuffle_up(), desc="Move window up"),
+    
+	# Size windows
+	Key([mod, "shift"], "n", lazy.layout.normalize(), desc="Reset all window sizes"),
+	Key([mod], "plus", lazy.layout.grow().when(layout=["monadtall", "monadwide"]), desc="Grow window"),
+	Key([mod], "minus", lazy.layout.shrink().when(layout=["monadtall", "monadwide"]), desc="Shrink window"),
+    
+	# Manage layouts
+	Key([mod], "Tab", lazy.next_layout(), desc="Toggle between layouts"),
+	Key([mod, "shift"], "f", lazy.window.toggle_fullscreen(), desc="Toggle fullscreen on the focused window"),
+	Key([mod, "shift"], "t", lazy.window.toggle_floating(), desc="Toggle floating on the focused window"),
+	Key([mod, "shift"], "b", lazy.hide_show_bar(), desc="Toggle bar visibility"),
+]
+
+
+### LAYOUTS ###
+groups = [Group(i) for i in "123456789"]
+
+# Switching between layouts
+for i in groups:
+	keys.extend(
+		[
+			Key([mod], i.name, lazy.group[i.name].toscreen(), desc="Switch to group {}".format(i.name)),
+			Key([mod, "shift"], i.name, lazy.window.togroup(i.name, switch_group=False), desc="Switch to & move focused window to group {}".format(i.name)),
+		]
+	)
+
+# Available layouts
+layouts = [
+	layout.MonadTall(border_focus=lightBlue, border_normal=lightGrey, border_width=2, margin=8, single_margin=0, single_border_width=0),
+	layout.Floating(),
+]
+
+# Drag floating layouts.
+mouse = [
+	Drag([mod], "Button1", lazy.window.set_position_floating(), start=lazy.window.get_position()),
+	Drag([mod], "Button3", lazy.window.set_size_floating(), start=lazy.window.get_size()),
+	Click([mod], "Button1", lazy.window.bring_to_front()),
+]
+
+
+### WIDGETS ###
+widget_defaults = dict(
+	font="sans, JetBrainsMono Nerd Font",
+	fontsize=15,
+	padding=3,
+)
+extension_defaults = widget_defaults.copy()
+
+# Display widgets on the bar
+screens = [
+	Screen(
+		top=bar.Bar(
+			[
+				widget.Clock(format=" %H:%M"),
+				widget.Sep(),
+				widget.Clock(format="󰃮 %a. %d.%m.%y"),
+				widget.Spacer(),
+				widget.GroupBox(highlight_method="line", this_current_screen_border=lightBlue),
+				widget.Spacer(),
+				widget.WidgetBox(text_closed="", text_open="" , widgets=[ 
+					widget.Systray()
+				]),
+				widget.Sep(),
+				widget.Wlan(format="󰖩  {essid}", interface="wlp2s0", update_interval=5, max_chars=4),
+				widget.Sep(),
+				widget.ThermalSensor(format="  {temp:.1f}{unit}", tag_sensor="CPU", threshold=90, update_interval=5),
+				widget.Sep(),
+				widget.PulseVolume(fmt="󰕾 {}"),
+				widget.Sep(),
+				widget.Backlight(fmt="󰃠 {}", backlight_name='amdgpu_bl0'),
+				widget.Sep(),
+				widget.Battery(format="󰁹 {percent:2.0%}"),
+			],
+			26,
+		),
+	),
+]
+
+
+### RULES ###
+dgroups_key_binder = None
+dgroups_app_rules = []  # type: list
+follow_mouse_focus = True
+bring_front_click = False
+floats_kept_above = True
+cursor_warp = False
+floating_layout = layout.Floating(
+	float_rules=[
+		# Run the utility of `xprop` to see the wm class and name of an X client.
+		*layout.Floating.default_float_rules,
+		Match(wm_class="confirmreset"),  # gitk
+		Match(wm_class="makebranch"),  # gitk
+		Match(wm_class="maketag"),  # gitk
+		Match(wm_class="ssh-askpass"),  # ssh-askpass
+		Match(title="branchdialog"),  # gitk
+		Match(title="pinentry"),  # GPG key password entry
+	]
+)
+auto_fullscreen = True
+focus_on_window_activation = "smart"
+reconfigure_screens = True
+
+auto_minimize = True
+
+wl_input_rules = None
+
+wmname = "LG3D"

modules/home/qtile/files/rofi-theme.rasi

@@ -0,0 +1,95 @@
+/*******************************************************************************
+ * ROFI SQUARED THEME USING THE NORD PALETTE 
+ * User                 : LR-Tech               
+ * Theme Repo           : https://github.com/lr-tech/rofi-themes-collection
+ *******************************************************************************/
+
+* {
+    font:   "JetBrainsMono Nerd Font Medium 12";
+
+    bg0:     #2E3440;
+    bg1:     #3B4252;
+    fg0:     #D8DEE9;
+
+    accent-color:     #88C0D0;
+    urgent-color:     #EBCB8B;
+
+    background-color:   transparent;
+    text-color:         @fg0;
+
+    margin:     0;
+    padding:    0;
+    spacing:    0;
+}
+
+window {
+    location:   center;
+    width:      480;
+
+    background-color:   @bg0;
+}
+
+inputbar {
+    spacing:    8px; 
+    padding:    8px;
+
+    background-color:   @bg1;
+}
+
+prompt, entry, element-icon, element-text {
+    vertical-align: 0.5;
+}
+
+prompt {
+    text-color: @accent-color;
+}
+
+textbox {
+    padding:            8px;
+    background-color:   @bg1;
+}
+
+listview {
+    padding:    4px 0;
+    lines:      8;
+    columns:    1;
+
+    fixed-height:   false;
+}
+
+element {
+    padding:    8px;
+    spacing:    8px;
+}
+
+element normal normal {
+    text-color: @fg0;
+}
+
+element normal urgent {
+    text-color: @urgent-color;
+}
+
+element normal active {
+    text-color: @accent-color;
+}
+
+element selected {
+    text-color: @bg0;
+}
+
+element selected normal, element selected active {
+    background-color:   @accent-color;
+}
+
+element selected urgent {
+    background-color:   @urgent-color;
+}
+
+element-icon {
+    size:   0.8em;
+}
+
+element-text {
+    text-color: inherit;
+}

modules/home/shell.nix

@@ -0,0 +1,71 @@
+{
+  config,
+  lib,
+  ...
+}: let
+  cfg = config.myConfig.shell;
+in {
+  options.myConfig.shell = {
+    bash.enable = lib.mkEnableOption "";
+    zsh.enable = lib.mkEnableOption "";
+    starship.enable = lib.mkEnableOption "";
+    nixAliases.enable = lib.mkEnableOption "";
+    improvedCommands.enable = lib.mkEnableOption "";
+    direnv.enable = lib.mkEnableOption "";
+  };
+
+  config = {
+    programs.bash.enable = cfg.bash.enable;
+
+    programs.zsh.enable = cfg.zsh.enable;
+
+    programs.starship = lib.mkIf cfg.starship.enable {
+      enable = true;
+      enableBashIntegration = cfg.bash.enable;
+      enableZshIntegration = cfg.zsh.enable;
+      settings = {
+        cmd_duration.disabled = true;
+        directory = {
+          truncation_length = 0;
+          truncation_symbol = "…/";
+          truncate_to_repo = false;
+        };
+      };
+    };
+
+    home.shellAliases = let
+      nixAliases = lib.mkIf cfg.nixAliases.enable {
+        nrs = "sudo nixos-rebuild switch";
+        nrb = "sudo nixos-rebuild boot";
+        nrrb = "nrb && reboot";
+        nrt = "sudo nixos-rebuild test";
+        nu = "sudo nix flake update";
+      };
+      commandAliases = lib.mkIf cfg.improvedCommands.enable {
+        ".." = "cd ..";
+        cat = "bat -p";
+      };
+    in
+      lib.mkMerge [nixAliases commandAliases];
+
+    programs.lsd = lib.mkIf cfg.improvedCommands.enable {
+      enable = true;
+      enableAliases = true;
+    };
+
+    programs.bat.enable = cfg.improvedCommands.enable;
+
+    programs.fzf.enable = cfg.improvedCommands.enable;
+
+    programs.zoxide = lib.mkIf cfg.improvedCommands.enable {
+      enable = true;
+      options = ["--cmd cd"];
+    };
+
+    programs.direnv = lib.mkIf cfg.direnv.enable {
+      enable = true;
+      nix-direnv.enable = true;
+      config.global.hide_env_diff = true;
+    };
+  };
+}

modules/home/ssh-client.nix

@@ -0,0 +1,21 @@
+{
+  config,
+  lib,
+  ...
+}: {
+  options.myConfig.ssh-client.enable = lib.mkEnableOption "";
+
+  config = lib.mkIf config.myConfig.ssh-client.enable {
+    programs.ssh = {
+      enable = true;
+
+      matchBlocks.kluebero-vm1 = {
+        hostname = "10.5.251.175";
+        user = "seb";
+        identitiesOnly = true;
+        identityFile = ["~/.ssh/kluebero/id_ed25519"];
+      };
+    };
+    services.ssh-agent.enable = true;
+  };
+}

modules/home/theming.nix

@@ -0,0 +1,45 @@
+{
+  config,
+  pkgs,
+  lib,
+  ...
+}: {
+  options.myConfig.theming.enable = lib.mkEnableOption "";
+
+  config = lib.mkIf config.myConfig.theming.enable {
+    dconf.settings."org/gnome/desktop/interface".color-scheme = "prefer-dark";
+
+    gtk = {
+      enable = true;
+
+      gtk2.configLocation = "${config.xdg.configHome}/gtk-2.0/gtkrc";
+
+      theme.name = "Adwaita-dark";
+      theme.package = pkgs.gnome.gnome-themes-extra;
+
+      iconTheme.name = "Adwaita";
+      iconTheme.package = pkgs.gnome.adwaita-icon-theme;
+
+      font.name = "Open Sans";
+      font.package = pkgs.open-sans;
+    };
+
+    qt = {
+      enable = true;
+      platformTheme = "gnome";
+      style.name = "adwaita-dark";
+      style.package = pkgs.adwaita-qt;
+    };
+
+    home.pointerCursor = {
+      name = "Bibata-Original-Classic";
+      package = pkgs.bibata-cursors;
+      size = 24;
+      x11.enable = true;
+      x11.defaultCursor = "X_cursor";
+      gtk.enable = true;
+    };
+
+    fonts.fontconfig.enable = true;
+  };
+}

modules/home/vscode.nix

@@ -0,0 +1,50 @@
+{
+  config,
+  pkgs,
+  lib,
+  ...
+}: {
+  options.myConfig.vscode.enable = lib.mkEnableOption "";
+
+  config = lib.mkIf config.myConfig.vscode.enable {
+    home.packages = [pkgs.nil];
+
+    programs.vscode = {
+      enable = true;
+      package = pkgs.vscodium;
+
+      mutableExtensionsDir = false;
+      extensions = [
+        pkgs.vscode-extensions.jnoortheen.nix-ide
+        pkgs.vscode-extensions.kamadorueda.alejandra
+        pkgs.vscode-extensions.pkief.material-icon-theme
+        pkgs.vscode-extensions.mkhl.direnv
+      ];
+    };
+
+    systemd.user.tmpfiles.rules = let
+      settings = builtins.replaceStrings ["\n"] ["\\n"] ''
+        {
+          "editor.fontFamily": "JetBrainsMono Nerd Font",
+          "explorer.confirmDelete": false,
+          "explorer.confirmDragAndDrop": false,
+          "extensions.autoCheckUpdates": false,
+          "files.autoSave": "afterDelay",
+          "git.autofetch": true,
+          "git.confirmSync": false,
+          "nix.enableLanguageServer": true,
+          "nix.serverPath": "nil",
+          "update.mode": "none",
+          "git.suggestSmartCommit": false,
+          "workbench.sideBar.location": "right",
+          "editor.renderWhitespace": "none",
+          "workbench.iconTheme": "material-icon-theme",
+          "editor.minimap.enabled": false
+        }
+      '';
+    in [
+      "f+ %h/.config/VSCodium/User/settings.json - - - - ${settings}"
+      "f+ %h/.config/VSCodium/User/settings-default.json - - - - ${settings}"
+    ];
+  };
+}

modules/system/auto-gc.nix

@@ -0,0 +1,15 @@
+{
+  config,
+  lib,
+  ...
+}: {
+  options.myConfig.auto-gc.enable = lib.mkEnableOption "";
+
+  config = lib.mkIf config.myConfig.auto-gc.enable {
+    nix.gc = {
+      automatic = true;
+      dates = "weekly";
+      options = "--delete-older-than 7d";
+    };
+  };
+}

modules/system/bluetooth.nix

@@ -0,0 +1,16 @@
+{
+  config,
+  lib,
+  ...
+}: {
+  options.myConfig.bluetooth.enable = lib.mkEnableOption "";
+
+  config = lib.mkIf config.myConfig.bluetooth.enable {
+    hardware.bluetooth = {
+      enable = true;
+      powerOnBoot = true;
+    };
+    services.blueman.enable = true;
+    hardware.logitech.wireless.enable = true;
+  };
+}

modules/system/boot.nix

@@ -0,0 +1,20 @@
+{
+  config,
+  lib,
+  ...
+}: {
+  options.myConfig.boot.systemd.enable = lib.mkEnableOption "";
+
+  config = lib.mkIf config.myConfig.boot.systemd.enable {
+    boot.tmp.cleanOnBoot = true;
+    boot.loader = {
+      systemd-boot = {
+        enable = true;
+        editor = false;
+        configurationLimit = 50;
+      };
+      efi.canTouchEfiVariables = true;
+      timeout = 3;
+    };
+  };
+}

modules/system/comma.nix

@@ -0,0 +1,16 @@
+{
+  inputs,
+  config,
+  lib,
+  ...
+}: {
+  imports = [inputs.nix-index-database.nixosModules.nix-index];
+
+  options.myConfig.comma.enable = lib.mkEnableOption "";
+
+  config = lib.mkIf config.myConfig.comma.enable {
+    programs.command-not-found.enable = false;
+    programs.nix-index.enable = true;
+    programs.nix-index-database.comma.enable = true;
+  };
+}

modules/system/de.nix

@@ -0,0 +1,18 @@
+{
+  config,
+  lib,
+  ...
+}: {
+  options.myConfig.de.qtile.enable = lib.mkEnableOption "";
+
+  config = lib.mkIf config.myConfig.de.qtile.enable {
+    services.xserver = {
+      enable = true;
+
+      windowManager.qtile.enable = true;
+      desktopManager.wallpaper.mode = "fill";
+    };
+
+    myConfig.x-input.enable = true;
+  };
+}

modules/system/default.nix

@@ -0,0 +1,19 @@
+{
+  imports = [
+    ./flatpak.nix
+    ./vm.nix
+    ./wlan.nix
+    ./doas.nix
+    ./vpn.nix
+    ./comma.nix
+    ./auto-gc.nix
+    ./sops.nix
+    ./bluetooth.nix
+    ./powersave.nix
+    ./x-input.nix
+    ./de.nix
+    ./dm.nix
+    ./sound.nix
+    ./boot.nix
+  ];
+}

modules/system/dm.nix

@@ -0,0 +1,20 @@
+{
+  config,
+  lib,
+  ...
+}: {
+  options.myConfig.dm.lightdm.enable = lib.mkEnableOption "";
+
+  config = lib.mkIf config.myConfig.dm.lightdm.enable {
+    services.xserver = {
+      enable = true;
+
+      displayManager.lightdm = {
+        enable = true;
+        greeters.slick.enable = true;
+      };
+    };
+
+    myConfig.x-input.enable = true;
+  };
+}

modules/system/doas.nix

@@ -0,0 +1,25 @@
+{
+  config,
+  lib,
+  ...
+}: {
+  options.myConfig.doas.enable = lib.mkEnableOption "";
+
+  config = lib.mkIf config.myConfig.doas.enable {
+    security.sudo.enable = false;
+
+    security.doas = {
+      enable = true;
+      extraRules = [
+        {
+          groups = ["wheel"];
+          keepEnv = true;
+          persist = true;
+        }
+      ];
+    };
+
+    environment.shellAliases.sudo = "doas";
+    programs.bash.interactiveShellInit = lib.mkIf config.myConfig.shell.bash.enable "complete -F _command doas";
+  };
+}

modules/system/flatpak.nix

@@ -0,0 +1,30 @@
+{
+  config,
+  pkgs,
+  lib,
+  ...
+}: {
+  options.myConfig.flatpak.enable = lib.mkEnableOption "";
+
+  config = lib.mkIf config.myConfig.flatpak.enable {
+    services.flatpak.enable = true;
+
+    xdg.portal = {
+      enable = true;
+      extraPortals = [pkgs.xdg-desktop-portal-gtk];
+      config.common.default = "*";
+    };
+
+    home-manager.sharedModules = [
+      {
+        xdg = {
+          enable = true;
+          systemDirs.data = [
+            "/var/lib/flatpak/exports/share"
+            "/home/seb/.local/share/flatpak/exports/share"
+          ];
+        };
+      }
+    ];
+  };
+}

modules/system/powersave.nix

@@ -0,0 +1,25 @@
+{
+  config,
+  lib,
+  ...
+}: {
+  options.myConfig.powersave.enable = lib.mkEnableOption "";
+
+  config = lib.mkIf config.myConfig.powersave.enable {
+    services.auto-cpufreq = {
+      enable = true;
+      settings = {
+        charger = {
+          governor = "powersave";
+          turbo = "never";
+          energy_performance_preference = "power";
+        };
+        battery = {
+          governor = "powersave";
+          turbo = "never";
+          energy_performance_preference = "power";
+        };
+      };
+    };
+  };
+}

modules/system/sops.nix

@@ -0,0 +1,17 @@
+{
+  inputs,
+  config,
+  lib,
+  ...
+}: {
+  imports = [inputs.sops-nix.nixosModules.sops];
+
+  options.myConfig.sops.enable = lib.mkEnableOption "";
+
+  config = lib.mkIf config.myConfig.sops.enable {
+    sops = {
+      age.sshKeyPaths = ["/etc/ssh/ssh_host_ed25519_key"];
+      defaultSopsFile = ../../hosts/dell-laptop/secrets.yaml;
+    };
+  };
+}

modules/system/sound.nix

@@ -0,0 +1,19 @@
+{
+  config,
+  lib,
+  ...
+}: {
+  options.myConfig.sound.pipewire.enable = lib.mkEnableOption "";
+
+  config = lib.mkIf config.myConfig.sound.pipewire.enable {
+    security.rtkit.enable = true;
+    hardware.pulseaudio.enable = false;
+    services.pipewire = {
+      enable = true;
+      wireplumber.enable = true;
+      alsa.enable = true;
+      alsa.support32Bit = true;
+      pulse.enable = true;
+    };
+  };
+}

modules/system/vm.nix

@@ -0,0 +1,28 @@
+{
+  config,
+  pkgs,
+  lib,
+  ...
+}: {
+  options.myConfig.vm.qemu.enable = lib.mkEnableOption "";
+
+  config = lib.mkIf config.myConfig.vm.qemu.enable {
+    virtualisation.libvirtd.enable = true;
+
+    programs.virt-manager.enable = true;
+
+    environment.systemPackages = [
+      pkgs.quickemu
+      pkgs.quickgui
+    ];
+
+    home-manager.sharedModules = [
+      {
+        dconf.settings."org/virt-manager/virt-manager/connections" = {
+          autoconnect = ["qemu:///system"];
+          uris = ["qemu:///system"];
+        };
+      }
+    ];
+  };
+}

modules/system/vpn.nix

@@ -0,0 +1,37 @@
+{
+  config,
+  lib,
+  ...
+}: {
+  options.myConfig.vpn.lgs.enable = lib.mkEnableOption "";
+
+  config = lib.mkIf config.myConfig.vpn.lgs.enable {
+    sops.secrets = {
+      "vpn/lgs/crt" = {};
+      "vpn/lgs/key" = {};
+    };
+
+    services.openvpn.servers.lgs = {
+      autoStart = false;
+
+      config = ''
+        dev tap
+        persist-tun
+        persist-key
+        data-ciphers AES-128-GCM:AES-256-CBC
+        data-ciphers-fallback AES-256-CBC
+        auth SHA1
+        tls-client
+        client
+        resolv-retry infinite
+        remote 194.9.190.11 1194 udp4
+        nobind
+        auth-user-pass
+        ca ${config.sops.secrets."vpn/lgs/crt".path}
+        tls-auth ${config.sops.secrets."vpn/lgs/key".path} 1
+        remote-cert-tls server
+        explicit-exit-notify
+      '';
+    };
+  };
+}

modules/system/wlan.nix

@@ -0,0 +1,96 @@
+{
+  config,
+  lib,
+  ...
+}: {
+  options.myConfig.wlan.enable = lib.mkEnableOption "";
+
+  config = lib.mkIf config.myConfig.wlan.enable {
+    sops.secrets."wlan.env" = {};
+
+    networking.networkmanager = {
+      enable = true;
+
+      ensureProfiles = {
+        environmentFiles = [config.sops.secrets."wlan.env".path];
+
+        profiles = {
+          home = {
+            connection = {
+              id = "home";
+              uuid = "24b856a6-27eb-4c4f-b85c-f59ab0824965";
+              type = "wifi";
+              interface-name = "wlp2s0";
+            };
+            wifi = {
+              mode = "infrastructure";
+              ssid = "$HOME_SSID";
+            };
+            wifi-security = {
+              auth-alg = "open";
+              key-mgmt = "wpa-psk";
+              psk = "$HOME_PSK";
+            };
+            ipv4 = {method = "auto";};
+            ipv6 = {
+              addr-gen-mode = "default";
+              method = "auto";
+            };
+          };
+
+          mobile = {
+            connection = {
+              id = "mobile";
+              uuid = "e3a749cf-a103-4e1e-a50c-4a4898bafcf6";
+              type = "wifi";
+              interface-name = "wlp2s0";
+            };
+            wifi = {
+              mode = "infrastructure";
+              ssid = "$MOBILE_SSID";
+            };
+            wifi-security = {
+              auth-alg = "open";
+              key-mgmt = "wpa-psk";
+              psk = "$MOBILE_PSK";
+            };
+            ipv4 = {method = "auto";};
+            ipv6 = {
+              addr-gen-mode = "default";
+              method = "auto";
+            };
+          };
+
+          school = {
+            connection = {
+              id = "school";
+              uuid = "bfdf4e7f-d2c4-4ab6-b833-37ecd5199b22";
+              type = "wifi";
+              interface-name = "wlp2s0";
+            };
+            wifi = {
+              mode = "infrastructure";
+              ssid = "$SCHOOL_SSID";
+            };
+            wifi-security = {
+              auth-alg = "open";
+              key-mgmt = "wpa-eap";
+            };
+            "802-1x" = {
+              domain-suffix-match = "lgs-hu.eu";
+              eap = "ttls;";
+              identity = "$SCHOOL_ID";
+              password = "$SCHOOL_PSK";
+              phase2-auth = "pap";
+            };
+            ipv4 = {method = "auto";};
+            ipv6 = {
+              addr-gen-mode = "default";
+              method = "auto";
+            };
+          };
+        };
+      };
+    };
+  };
+}

modules/system/x-input.nix

@@ -0,0 +1,29 @@
+{
+  config,
+  lib,
+  ...
+}: {
+  options.myConfig.x-input.enable = lib.mkEnableOption "";
+
+  config = lib.mkIf config.myConfig.x-input.enable {
+    services.xserver = {
+      enable = true;
+      xkb = {
+        layout = "de";
+        variant = "nodeadkeys";
+      };
+
+      libinput = {
+        enable = true;
+
+        touchpad = {
+          accelProfile = "adaptive";
+          naturalScrolling = true;
+          disableWhileTyping = true;
+        };
+
+        mouse.accelProfile = "flat";
+      };
+    };
+  };
+}