SebastianStork/nixos-config
1
0
Fork 0
mirror of https://github.com/SebastianStork/nixos-config.git synced 2026-01-22 04:34:25 +01:00
Code Issues Projects Releases Packages Wiki Activity Actions

Enable nextcloud on alto

Browse source
This commit is contained in:
SebastianStork 2025-04-09 20:35:04 +02:00
parent dd03ad4fde
commit 7c1275b0de
7 changed files with 241 additions and 4 deletions
Download patch file Download diff file Expand all files Collapse all files

51
modules/system/nextcloud/backups.nix Normal file
View file

@ -0,0 +1,51 @@
{
config,
pkgs,
lib,
...
}:
let
cfg = config.myConfig.nextcloud;
user = config.users.users.nextcloud.name;
inherit (config.users.users.nextcloud) group;
in
{
options.myConfig.nextcloud.backups.enable = lib.mkEnableOption "";
config = lib.mkIf cfg.backups.enable {
systemd.tmpfiles.rules = [ "d ${cfg.dataDir}/backup 700 ${user} ${group} -" ];
myConfig.resticBackup.nextcloud = {
inherit user;
healthchecks.enable = true;
extraConfig = {
backupPrepareCommand = ''
${lib.getExe' config.services.nextcloud.occ "nextcloud-occ"} maintenance:mode --on
${lib.getExe' config.services.postgresql.package "pg_dump"} nextcloud --format=custom --file=${cfg.dataDir}/backup/db.dump
'';
backupCleanupCommand = ''
${lib.getExe' config.services.nextcloud.occ "nextcloud-occ"} maintenance:mode --off
'';
paths = [
"${cfg.dataDir}/home/data"
"${cfg.dataDir}/home/config/config.php"
"${cfg.dataDir}/backup"
];
};
};
environment.systemPackages = [
(pkgs.writeShellApplication {
name = "nextcloud-restore";
text = ''
sudo --user=${user} ${lib.getExe' config.services.nextcloud.occ "nextcloud-occ"} maintenance:mode --on
sudo --user=${user} restic-nextcloud restore --target / latest
sudo --user=${user} pg_restore --clean --if-exists --dbname nextcloud ${cfg.dataDir}/backup/db.dump
sudo --user=${user} ${lib.getExe' config.services.nextcloud.occ "nextcloud-occ"} maintenance:mode --off
'';
})
];
};
}

94
modules/system/nextcloud/default.nix Normal file
View file

@ -0,0 +1,94 @@
{
config,
inputs,
pkgs,
lib,
...
}:
let
cfg = config.myConfig.nextcloud;
user = config.users.users.nextcloud.name;
inherit (config.users.users.nextcloud) group;
in
{
options.myConfig.nextcloud = {
enable = lib.mkEnableOption "";
subdomain = lib.mkOption {
type = lib.types.nonEmptyStr;
default = "";
};
dataDir = lib.mkOption {
type = lib.types.path;
default = config.services.nextcloud.home;
readOnly = true;
};
port = lib.mkOption {
type = lib.types.port;
default = 80;
readOnly = true;
};
};
config = lib.mkIf cfg.enable {
sops.secrets."nextcloud/admin-password" = {
owner = user;
inherit group;
};
systemd.tmpfiles.rules = [ "d ${cfg.dataDir}/home 750 ${user} ${group} -" ];
services.nextcloud = {
enable = true;
package = pkgs.nextcloud30;
hostName = "${cfg.subdomain}.${config.networking.domain}";
database.createLocally = true;
config = {
dbtype = "pgsql";
adminuser = "admin";
adminpassFile = config.sops.secrets."nextcloud/admin-password".path;
};
https = true;
settings = {
overwriteProtocol = "https";
trusted_proxies = [ "127.0.0.1" ];
log_type = "file";
default_phone_region = "DE";
maintenance_window_start = "2"; # UTC
defaultapp = "side_menu";
};
configureRedis = true;
maxUploadSize = "16G";
phpOptions."opcache.interned_strings_buffer" = "16";
autoUpdateApps = {
enable = true;
startAt = "04:00:00";
};
extraApps = {
inherit (config.services.nextcloud.package.packages.apps)
calendar
contacts
deck
onlyoffice
;
twofactor_totp = pkgs.fetchNextcloudApp {
url = inputs.nextcloud-twofactor-totp.outPath;
sha256 = inputs.nextcloud-twofactor-totp.narHash;
license = "agpl3Plus";
unpack = true;
};
side_menu = pkgs.fetchNextcloudApp {
url = inputs.nextcloud-side-menu.outPath;
sha256 = inputs.nextcloud-side-menu.narHash;
license = "agpl3Plus";
unpack = true;
};
};
};
};
}