Enable nextcloud on alto

modules/system/nextcloud/backups.nix

@@ -0,0 +1,51 @@
+{
+  config,
+  pkgs,
+  lib,
+  ...
+}:
+let
+  cfg = config.myConfig.nextcloud;
+
+  user = config.users.users.nextcloud.name;
+  inherit (config.users.users.nextcloud) group;
+in
+{
+  options.myConfig.nextcloud.backups.enable = lib.mkEnableOption "";
+
+  config = lib.mkIf cfg.backups.enable {
+    systemd.tmpfiles.rules = [ "d ${cfg.dataDir}/backup 700 ${user} ${group} -" ];
+
+    myConfig.resticBackup.nextcloud = {
+      inherit user;
+      healthchecks.enable = true;
+
+      extraConfig = {
+        backupPrepareCommand = ''
+          ${lib.getExe' config.services.nextcloud.occ "nextcloud-occ"} maintenance:mode --on
+          ${lib.getExe' config.services.postgresql.package "pg_dump"} nextcloud --format=custom --file=${cfg.dataDir}/backup/db.dump
+        '';
+        backupCleanupCommand = ''
+          ${lib.getExe' config.services.nextcloud.occ "nextcloud-occ"} maintenance:mode --off
+        '';
+        paths = [
+          "${cfg.dataDir}/home/data"
+          "${cfg.dataDir}/home/config/config.php"
+          "${cfg.dataDir}/backup"
+        ];
+      };
+    };
+
+    environment.systemPackages = [
+      (pkgs.writeShellApplication {
+        name = "nextcloud-restore";
+        text = ''
+          sudo --user=${user} ${lib.getExe' config.services.nextcloud.occ "nextcloud-occ"} maintenance:mode --on
+          sudo --user=${user} restic-nextcloud restore --target / latest
+          sudo --user=${user} pg_restore --clean --if-exists --dbname nextcloud ${cfg.dataDir}/backup/db.dump
+          sudo --user=${user} ${lib.getExe' config.services.nextcloud.occ "nextcloud-occ"} maintenance:mode --off
+        '';
+      })
+    ];
+  };
+}

modules/system/nextcloud/default.nix

@@ -0,0 +1,94 @@
+{
+  config,
+  inputs,
+  pkgs,
+  lib,
+  ...
+}:
+let
+  cfg = config.myConfig.nextcloud;
+
+  user = config.users.users.nextcloud.name;
+  inherit (config.users.users.nextcloud) group;
+in
+{
+  options.myConfig.nextcloud = {
+    enable = lib.mkEnableOption "";
+    subdomain = lib.mkOption {
+      type = lib.types.nonEmptyStr;
+      default = "";
+    };
+    dataDir = lib.mkOption {
+      type = lib.types.path;
+      default = config.services.nextcloud.home;
+      readOnly = true;
+    };
+    port = lib.mkOption {
+      type = lib.types.port;
+      default = 80;
+      readOnly = true;
+    };
+  };
+
+  config = lib.mkIf cfg.enable {
+    sops.secrets."nextcloud/admin-password" = {
+      owner = user;
+      inherit group;
+    };
+
+    systemd.tmpfiles.rules = [ "d ${cfg.dataDir}/home 750 ${user} ${group} -" ];
+
+    services.nextcloud = {
+      enable = true;
+      package = pkgs.nextcloud30;
+      hostName = "${cfg.subdomain}.${config.networking.domain}";
+
+      database.createLocally = true;
+      config = {
+        dbtype = "pgsql";
+        adminuser = "admin";
+        adminpassFile = config.sops.secrets."nextcloud/admin-password".path;
+      };
+
+      https = true;
+      settings = {
+        overwriteProtocol = "https";
+        trusted_proxies = [ "127.0.0.1" ];
+        log_type = "file";
+        default_phone_region = "DE";
+        maintenance_window_start = "2"; # UTC
+        defaultapp = "side_menu";
+      };
+
+      configureRedis = true;
+      maxUploadSize = "16G";
+      phpOptions."opcache.interned_strings_buffer" = "16";
+
+      autoUpdateApps = {
+        enable = true;
+        startAt = "04:00:00";
+      };
+      extraApps = {
+        inherit (config.services.nextcloud.package.packages.apps)
+          calendar
+          contacts
+          deck
+          onlyoffice
+          ;
+
+        twofactor_totp = pkgs.fetchNextcloudApp {
+          url = inputs.nextcloud-twofactor-totp.outPath;
+          sha256 = inputs.nextcloud-twofactor-totp.narHash;
+          license = "agpl3Plus";
+          unpack = true;
+        };
+        side_menu = pkgs.fetchNextcloudApp {
+          url = inputs.nextcloud-side-menu.outPath;
+          sha256 = inputs.nextcloud-side-menu.narHash;
+          license = "agpl3Plus";
+          unpack = true;
+        };
+      };
+    };
+  };
+}

modules/system/tailscale/caddy-serve.nix

@@ -0,0 +1,69 @@
+{
+  config,
+  pkgs-unstable,
+  lib,
+  ...
+}:
+let
+  nodes = config.myConfig.tailscale.caddyServe |> lib.filterAttrs (_: value: value.enable);
+
+  caddy-tailscale = pkgs-unstable.caddy.withPlugins {
+    plugins = [ "github.com/tailscale/caddy-tailscale@v0.0.0-20250207163903-69a970c84556" ];
+    hash = "sha256-UR9CG/zIslkXHDj1fDWmhx8hJZ8VLvZzOTGvGqqx1Ls=";
+  };
+in
+{
+  options.myConfig.tailscale.caddyServe = lib.mkOption {
+    type = lib.types.attrsOf (
+      lib.types.submodule (
+        { name, ... }:
+        {
+          options = {
+            enable = lib.mkEnableOption "" // {
+              default = true;
+            };
+            subdomain = lib.mkOption {
+              type = lib.types.nonEmptyStr;
+              default = name;
+            };
+            port = lib.mkOption {
+              type = lib.types.nullOr lib.types.port;
+              default = null;
+            };
+          };
+        }
+      )
+    );
+    default = { };
+  };
+
+  config = lib.mkIf (nodes != { }) {
+    sops.secrets."service-tailscale-auth-key" = {
+      owner = config.services.caddy.user;
+      inherit (config.services.caddy) group;
+    };
+
+    services.caddy = {
+      enable = true;
+      package = caddy-tailscale;
+      enableReload = false;
+
+      globalConfig = ''
+        tailscale {
+          auth_key {file.${config.sops.secrets."service-tailscale-auth-key".path}}
+        }
+      '';
+
+      virtualHosts = lib.mapAttrs' (
+        _: value:
+        lib.nameValuePair "https://${value.subdomain}.${config.networking.domain}" {
+          extraConfig = ''
+            bind tailscale/${value.subdomain}
+            tailscale_auth
+            reverse_proxy localhost:${toString value.port}
+          '';
+        }
+      ) nodes;
+    };
+  };
+}